#Tutorial #7 – Challenges Part 1

## Overview

This tutorial will show a few examples of how to create deathless, damageless, and weapon limited challenge achievements. A second tutorial is planned after to cover speedrun and other time related challenges. The topic of challenge achievements is very broad and what appropriate for a game are completely dependent on the game mechanics. The game [Mega Man](<https://retroachievements.org/game/1448>) was chosen for this tutorial because it is tough yet fair game that has very little Random Number Generator (RNG) events which could mess up a damageless/deathless run. With enough practice, skill, game mechanic knowledge, and patience damageless runs of the entire game are achievable (see [Mr. Perfect](https://retroachievements.org/achievement/53290) from the [Mega Man Bonus](https://retroachievements.org/game/6729) set). <br>

![Mega Man Title Screen](Mega\_Man\_Title.png)<br>



## Challenge Indicators

\*\*Challenge indicators\*\* will appear on the screen when a player is close to obtaining an achievement. The achievement will also appear as \*\*primed\*\* if the player opens up the Retro Achievement overlay. An achievement is considered \*\*primed\*\* when all of the conditions, except for the conditions with a \*\*trigger\*\* flag on them, have been met. Challenge indicators give feedback to the player of when an achievement is still achievable and, more importantly, when a challenge has been failed. It is good practice to keep the number of primed achievements to a minimum to reduce visual clutter. <br>

For example, a damageless boss achievement should only be \*\*primed\*\* while fighting the boss. If the player takes damage the challenge indicator should disappear to let the player know they failed the challenge and won’t receive achievement for this fight. The challenge achievement should not appear again until the player goes for a rematch with the boss. Similarly, a deathless level achievement should only be \*\*primed\*\* during the challenge level. If the player dies during the level the challenge indicator should disappear until the player retires the level in a different play through. We will go more in-depth with the following Mega Man examples to show how to code challenges with RAScripts.

## Leaderboard Analogy

This tutorial will use leaderboard terminology to for the different type of conditions used in a challenge. We will cover how to script leaderboards in a later tutorial with an eventual goal of making synchronized challenge achievements and leaderboards that start, cancel, and submit with the same code.

### Start

The start condition for a challenge achievement is an event that occurs right before the challenge has started. This start event should not occur again during the challenge otherwise the challenge maybe restarted if the player fails in the middle. Use the ```once()``` around the start condition to add a hit that will keep the challenge active and show a challenge indicator. A more complex start condition may require multiple conditions in an AndNext chain with a hit on the last condition which can be accomplish by wrapping the complex condition in a ```once()```. Multiple start conditions can be coded by putting each start condition in its own Alt.

### Cancel

The cancel conditions for a challenge achievement are events that will reset the hit from the start condition. The cancel condition will remove the challenge indicator from the screen if the achievement was \*\*primed\*\*. There will often be multiple cancel conditions for events like a game over, a level change, and any unique events for the challenge. Each cancel event should be wrapped in a ```never()``` command which add a ResetIf flag to the condition. If a cancel event is multiple conditions then put of all in the ```never()``` command to create an AndNext chain.


### Submit

The submit condition for a challenge achievement is the event that occur once the challenge has been completed. If the start condition hit has not been reset by the cancel condition then the achievement will trigger when the submit conditions are met. Using the ```trigger\_when()``` command for all of the submit conditions will put a trigger flag to the conditions. If a submit event is multiple conditions then put of all in the ``` trigger\_when()``` command to create an AndNext chain.

# Example 7A: Blue Bomber

Mega Man is one of the earliest games to give the player the freedom of playing the stages in any order. When the player defeats a boss they acquire the boss’s special weapon which they can use for the rest of the game. Every boss has a weakness to one of the special weapon so there is an optimal order to beating each which will make the game a little easier. However, you do not need to exploit the boss’s weakness and every boss can be defeated using the weapon, the Mega Buster. Bombman is one of the easier bosses to beat which is why he was chosen for the damageless example. Note the achievement can easily be modified for any of the other five bosses by changing the stage number and where the ready room is in the level.

![Mega Man Fighting Bombman](Mega\_Man\_Bombman.png)<br>



```

// Mega Man

// #ID = 1448

// $001B: Universal stage scrolling progress big parts

function StageBombmanBoss() => byte(0x00001B) == 22

// $0031: Stage id

function StageID() => byte(0x000031)

// $0041: Solid pause

function SolidPause() => byte(0x000041) == 1

// $006A: Health

function Health() => byte(0x00006A)

// $00BB: Stage clear flag

function StageClear() => byte(0x0000BB) == 1

// Start at the beginning of the Bombman boss fight

bombmanDamagelessStart = once(StageBombmanBoss() && StageID() == 2)

// Cancel if health lost or the pause glitch used

bombmanDamagelessCancel = never(Health() < prev(Health())) &&

never(SolidPause())

// Submit when the stage is cleared

bombmanDamagelessSubmit = trigger\_when(StageClear())

achievement(

title = "Example 7A: Blue Bomber",

description = "Defeat Bombman without taking damage (pause glitch not allowed)",

points = 10,

trigger = bombmanDamagelessStart && bombmanDamagelessCancel && bombmanDamagelessSubmit

)```

## Start Conditions

The challenge is set to begin when the player enters the boss’s ready room right before the fight. To keep the \*\*challenge indicator\*\* active during the fight a ```once()``` command records a hit while in the ready room. It is important the condition used to start the challenge does not occur during the challenge. If the start condition occur during the bosses fight the challenge may be restarted even if the player has taken damage. For damageless challenges it is ideal if you have the start condition occur in-between the end of the level and before the boss fight.

## Cancel Conditions


The challenge will cancel if the player is not on Bombman’s stage, takes damage, or pauses the game. Each of these cancel conditions use a ```never``` command to reset the hit on the start condition, thus removing the challenge indicator and blocking the player from getting the achievement if they beat the boss. The cancel condition for taking damage is self-explanatory however the other two cancel conditions might not be so obvious. The canceling when we are not in Bombman stage will reset the challenge if any other stage. Canceling on pause is game specific, Mega Man has an infamous glitch that allows the boss damage cool down timer to continue counting down while the game is paused. The result is that you can hit the boss multiple times with one shot if you mash the pause button while the projectile is over them. By canceling on pause we don’t give the player credit for beating the boss with the pause glitch.

## Submit Conditions

The challenge will be triggered when the submit conditions are true. The submit conditions use a ```trigger\_when()``` command to add a trigger flag to this condition. Since the boss beat flag is the condition to be met putting a trigger flag on the condition will cause a challenge indicator to appear while fighting the boss. It is important that the submit conditions do not occur until the boss is defeated or the achievement will trigger prematurely.

# Example 7B: MM1 Survivalist I (Bombman)

Mega Man is a difficult game that relies on quick reaction time, knowledge of enemy patterns, and memorization of the order for disappearing blocks. However, the game has very little Random Number Generation (RNG) so once you learn a pattern it will be the same the next time. Despite its difficulty, completing a stage without dying is a reasonable challenge that most players can complete with a little practice. Bombman has one of the easier stages to beat which is why he was chosen for the deathless stage example.



![Mega Man on the Bombman stage](Mega\_Man\_Survival.png)<br>

```

// Mega Man

// #ID = 1448

// $001B: Universal stage scrolling progress big parts

function StageStart() => byte(0x00001B) == 1

// $0031: Stage id

function StageID() => byte(0x000031)

// $0036: [8-bit] Stage Select (0xbd when selecting stage)

function StageSelect() => byte(0x000036) == 0xbd

// $0041: Solid pause

function SolidPause() => byte(0x000041) == 1

// $0071: Ammount of Magnet Beam left

function MagnetBeamAmmo() => byte(0x000071)

// $00A6: Lives

function Lives() => byte(0x0000A6)

// $00BB: Stage clear flag

function StageClear() => byte(0x0000BB) == 1

// Start at the beginning of the stage

bombmanDeathlessStart = once(StageStart() && StageID() == 2)

// Cancel if on stage selection screen, life lost, pause glitch used, or magnet gun used

bombmanDeathlessCancel = never(StageSelect()) &&

never(prev(Lives()) > Lives()) &&

never(SolidPause()) &&

never(prev(MagnetBeamAmmo()) > MagnetBeamAmmo())

// Submit when the stage is cleared

bombmanDeathlessSubmit = trigger\_when(StageClear())

achievement(

title = "Example 7B: MM1 Survivalist I (Bombman)",

description = "Complete Bombman's Stage without losing a life, pausing, or Magnet Beam (Weapon Menu is OK)",

points = 5,

trigger = bombmanDeathlessStart && bombmanDeathlessCancel && bombmanDeathlessSubmit

)

```

## Start Conditions

The challenge is set to begin when the player is at the very first screen of the Bombman stage. To keep the \*\*challenge indicator\*\* active during the fight a ```once()``` command records a hit while on first screen of the Bombman stage. The challenge will restart if the player dies early in the stage and since they will be spawn back at the beginning. Once the player gets past the first check point they will to survive until they beat Bombman.

## Cancel Conditions

## Submit Conditions

# Example 7C: Master of the Robot Busters (B)

## Mega Weapons

| Address | Weapon Type |

|:-------:|---------------------|

| $006B | Rolling Cutter Ammo |

| $006C | Ice Slasher Ammo |

| $006D | Hyper Bomb Ammo |

| $006E | Fire Storm Ammo |

| $006F | Thunder Beam Ammo |

| $0070 | Power Arm Ammo |

| $0071 | Magnet Beam Ammo |

## Homework #7

# Tutorial #7 Solution